Apex Tips: PL/SQL - COMO FAZER REQUISIÇÕES HTTPS

Um belo dia, estamos desenvolvendo nosso sistema e nos deparamos com a necessidade de fazer requisições https a partir do código PL/SQL. Daí pensamos: Sem problemas! Sendo bons profissionais, pesquisamos, como manda o figurino, na documentação oficial, mas, ao folhear dezenas de páginas, logo bate a sensação de que ela é demasiado densa para uma tarefa aparentemente tão simples. Sendo realistas com nossos prazos, buscamos aquele bloco de código amigo que deve estar nos esperando perdido em algum lugar da internet. Afinal, não é possível que ninguém nunca tenha feito uma requisição dentro de um bloco PLSQL! A felicidade que sentimos ao encontrá-lo rapidamente é substituída pela decepção de ver os erros explodindo na tela. Sendo assim, entendemos que é hora de tomar uma água e fazer o café porque a tarefa não será tão simples.

Nesse artigo vamos descrever os passos necessários para fazer nossas tão desejadas requisições. São 3 ações principas:

O usuário que fará a requisição precisa de grant de execução na package utl_http.
É necessário configurar ACLs.
Para requisições https, cada url alvo deverá ter seu certificado guardado no servidor de banco de dados em um wallet.

PACKAGE UTL_HTTP

Logue no banco de dados como SYS e conceda ao usuário que fará as requisições grant de execução na package utl_http.

grant execute on utl_http to APP;

Obs: Não esqueça de se certificar de que está no container ao qual o usuário pertence. Se não estiver, uma forma de conectar é:

alter session set container = pdb1;

CONFIGURAR ACL

A partir do Oracle 11g, o acesso a serviço de rede se dá por ACL, Listas de Controle de Acesso. Essas listas indicam quais usuários acessam quais recursos de rede. Para isso, utilizamos a package DBMS_NETWORK_ACL_ADMIN. Basicamente, vamos criar uma Lista de Controle de Acesso e atribuir o host, ou os hosts, a essa lista. Execute o comando abaixo como SYS ou SYSTEM.

     
  
begin 

    -- Cria a ACL 
    dbms_network_acl_admin.create_acl( 
        acl         => 'network_services.xml', 
        description => 'FTP ACL'             ,
        principal   => 'APP'                 ,
        is_grant    => true                  ,  
        privilege   => 'connect' 
    );

     -- Se quiser adicionar outro usuário. 
    dbms_network_acl_admin.add_privilege( 
        acl       => 'network_services.xml', 
        principal => 'APP2'                , 
        is_grant  => true                  , 
        privilege => 'connect' 
    ); 

    dbms_network_acl_admin.assign_acl(
        acl  => 'network_services.xml', 
        host => '*' 
    ); 

    commit; 

end;

Obs: Perceba que usamos o mesmo nome de arquivo, network_services.xml, tanto em dbms_network_acl_admin.create_acl como em dbms_network_acl_admin.assign_acl.

Se, posteriormente, você desejar criar ACL para outro usuário do banco, pode executar apenas o seguinte trecho:

     
  
begin 

     -- Se quiser adicionar outro usuário. 
    dbms_network_acl_admin.add_privilege( 
        acl       => 'network_services.xml', 
        principal => 'APP2'                , 
        is_grant  => true                  , 
        privilege => 'connect' 
    ); 

    commit; 

end;

Agora nosso código amigo já consegue fazer requisições http!

  
declare
req utl_http.req;
resp utl_http.resp;
value varchar2(32767);

begin

  req := utl_http.begin_request('http://dba-oracle.com');
  utl_http.set_header(req, 'User-Agent', 'Mozilla/4.0');
  resp := utl_http.get_response(req);

  loop

    utl_http.read_line(resp, value, true);
    dbms_output.put_line(value);

  end loop;

  utl_http.end_response(resp);

  exception when utl_http.end_of_body then

      utl_http.end_response(resp);

end;

CRIAR WALLETS

Chegou a hora de fazer requisições https. Mas, para isso, vamos precisar de alguns passos adicionais:

Obter o certificado da url que desejamos acessar.
Criar um oracle wallet para armazenar o certificado.

Se não souber como obter o certificado, leia o artigo: OBTER CERTIFICADOS A PARTIR DO NAVEGADOR WEB

Agora que temos nosso certificado, vamos salvá-lo em algum diretório no nosso servidor. Nesse exemplo, em /home/oracle.

Vamos criar um diretório onde adicionaremos nosso wallet.

mkdir -p u01/app/oracle/admin/cdb/wallet

Usando o utilitário orapki, vamos criar o wallet propiamente dito.

orapki wallet create -wallet /u01/app/oracle/admin/cdb/wallet -pwd Adm1n@2022 -auto_login

Atenção!

Aqui usamos a senha Adm1n@2022. O erro "Unable to save wallet at u01/app/oracle/admin/cdb/wallet" pode ser disparado se a senha não satisfizer os requisitos necessários que são: mínimos de 8 caracteres com letras e números.

Vamos adicionar o certificado que baixamos e está em /home/oracle no wallet.

orapki wallet add -wallet /u01/app/oracle/admin/cdb/wallet -trusted_cert -cert "/home/oracle/google-certificado.cer" -pwd Adm1n@2022

Se quisermos adicionar mais certificados ao nosso wallet, basta repetir esse útimo passo.

Tudo pronto para fazer nossa requisição https! Mas, antes, um último detalhe. Precisamos acrescentar uma linha ao nosso código.

utl_http.set_wallet('file:/u01/app/oracle/admin/cdb/wallet', 'Adm1n@2022');

Por fim, nosso código pronto para a tão esperada requisição https:

   
declare
req utl_http.req;
resp utl_http.resp; value varchar2(32767); 

begin 

  utl_http.set_wallet('file:/u01/app/oracle/admin/cdb/wallet', 'Adm1n@2022'); 
  req := utl_http.begin_request('https://www.google.com'); 
  utl_http.set_header(req, 'User-Agent', 'Mozilla/4.0'); 
  utl_http.set_body_charset(req,'UTF-8');
  resp := utl_http.get_response(req); 

  loop utl_http.read_line(resp, value, true);     
   	dbms_output.put_line(value);     
  end loop; 

  utl_http.end_response(resp); 

  exception when utl_http.end_of_body then 
      utl_http.end_response(resp);

end;

Espero que tenha ajudado a superar esse desafio. Seguem alguns links que podem ajudar a entender mais sobre o assunto:

UTL_HTTP and SSL (HTTPS) using Oracle Wallets

Fine-Grained Access to Network Services in Oracle Database 11g Release 1

Oracle UTL_HTTP Package

Oracle ACL Tips